module tentacular learn10tac <https://purl.org/learn/tentacular#> is

  import [ dc learn learn2sect skos xsd ]

  @skos:prefLabel = [
    "Tentacular Learning Ontology"@en
    "Ontogogi om tentakulær læring"@da
  ]
  @dc:description = "Domain-specific ontology for Tentacular Learning as defined by Ernst Schraube"@en
  @dc:created = @xsd:date(2024-04-26)
  @dc:creator = <https://dr.jones.dk/me/#me>
  @dc:license = <https://spdx.org/licenses/AGPL-3.0-or-later>

  structure WorldingPracticeLearning is
    @rdfs:subClassOf = learn:Process
    @skos:prefLabel = [
      "Learning as a Worlding Practice"@en
      "Læring som en verdeningspraksis"@da
    ]
    @dc:description = [
      "The process of learning viewed as an affinitive dialogue with the surrounding world"@en
      "Læringsproces anskuet som en gensidig dialog (affinitet) med den omkringliggende verden"@da
    ]
    @owl:disjointWith = learn2sect:BisectedLearning
    isPracticedBy -> learn:Learner
  end

  entity TentacularLearning is
    @rdfs:subClassOf = learn:Cognition
    @skos:prefLabel = [
      "Tentakular Learning"@en
      "Tentakulær læring"@da
    ]
    identity id -> unknown
  end

  entity Content is
    @rdfs:subClassOf = :WorldingPracticeLearning
    @rdfs:subClassOf = :ContentDimension
    @skos:prefLabel = [
      "Learning Content"@en
      "Læringsindhold"@da
    ]
    @skos:altLabel = [
      "The 'what' of learning"@en
      "Lærings 'hvad'"@da
    ]
    @dc:description = [
      "What the learner would like to learn"@en
      "Hvad eleven gerne vil lære"@da
    ]
    identity id -> unknown

    precedesReason -> ActionReason
  end

  entity ActionReason is
    @rdfs:subClassOf = :WorldingPracticeLearning
    @rdfs:subClassOf = :ContentDimension
    @skos:prefLabel = [
      "Action Reason"@en
      "Aktionsgrund"@da
    ]
    @skos:altLabel = [
      "The 'why' of learning"@en
      "Lærings 'hvorfor'"@da
    ]
    @dc:description = [
      "Subjective reason by the learner for initiating a learning process"@en
      "Subjektiv grund hos eleven til at igangsætte en læringsproces"@da
    ]
    identity id -> unknown

    affectsMode -> Mode
    precedesMethod -> Method
  end

  entity ExpansiveReason is
    @rdfs:subClassOf = ActionReason
    @skos:prefLabel = [
      "Expansive Reason"@en
      "Ekspansiv grund"@da
    ]
    identity id -> unknown

    causesExpansiveMode -> ExpansiveMode
  end

  entity DefensiveReason is
    @rdfs:subClassOf = ActionReason
    @skos:prefLabel = [
      "Defensive Reason"@en
      "Defensiv grund"@da
    ]
    identity id -> unknown

    causesDefensiveMode -> DefensiveMode
  end

  entity ReasoningTrap is
    @skos:prefLabel = [
      "Reasoning trap"@en
      "Fejlslutning"@da
    ]
    @dc:description = [
      "typical pitfalls in the construction of subjective reasons for action towards learning"@en
      "typiske faldgruber i konstruktionen af subjektive grunde til at igangsætte en læringsproces"@da
    ]
    identity id -> unknown

    trapsReason -> ActionReason
  end

  entity OnlineModeTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Online Mode Habit Trap"@en
      "Online-aktivitetsvanefælde"@da
    ]
    @dc:description = [
      "Considering the online mode and the use of digital devices as absolutely helpful and expanding learning."@en
      "Anskuelsen af online-aktivitet og brug af digitalt udstyr som altid hjælpsomt og læringsudvidende."@da
    ]
    identity id -> unknown
  end

  entity BisectedLearningTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Trap of Bisected Learning"@en
      "Fælde ved tvedelt læring"@da
    ]
    @dc:description = [
      "Deprioritization of the content dimension of learning, caused by bisected learning excluding learners from influence on it."@en
      "Nedprioritering af den indholdsdimensionen af læring, fordi tvedelt læring udelukker elever indflydelse herpå."@da
    ]
    identity id -> unknown
  end

  entity UncertainnessEffortlessnessTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Trap of Uncertainness and Effortlessness"@en
      "Uvisheds- og ubesværethedsfælde"@da
    ]
    @skos:altLabel = [
      "Trap of Uncertainness"@en
      "Trap of Effortlessness"@en
      "Uvishedsfælde"@da
      "Ubesværethedsfælde"@da
    ]
    @dc:description = [
      "Equating swiftness in arriving at a conclusion with learning progress."@en
      "Forveksling af hurtigt at nå til en løsning med læringsfremskridt."@da
    ]
    identity id -> unknown
  end

  entity DialogueReductionTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Online dialogue-reduction habit trap"@en
      "Online-dialogreduktionsvanefælde"@da
    ]
    @dc:description = [
      "Reducing dialogue to the operative exchange and back and forth of perspectives."@en
      "Reduktion af samtale til operativ udveksling af perspektiver."@da
    ]
    identity id -> unknown
  end

  entity Method is
    @rdfs:subClassOf = :WorldingPracticeLearning
    @skos:prefLabel = [
      "Learning Method"@en
      "Læringsmetode"@da
    ]
    @skos:altLabel = [
      "The 'how' of learning"@en
      "Lærings 'hvordan'"@da
    ]
    @dc:description = [
      "How the learning process is carried out by the learner"@en
      "Hvordan læringsprocessen bliver udført af eleven"@da
    ]
    identity id -> unknown

    precedesEvaluation -> Evaluation
  end

  entity Evaluation is
    @rdfs:subClassOf = :WorldingPracticeLearning
    @skos:prefLabel = [
      "Learning Evaluation"@en
      "Læringsevaluering"@da
    ]
    @dc:description = [
      "check by the learner whether what one wanted to learn through the learning process was also achieved"@en
      "Tjek af eleven hvorvidt den ønskede læring gennem læringsprocessen også blev opnået"@da
    ]
    identity id -> unknown
  end

  entity Mode is
    @skos:prefLabel = [
      "Mode"@en
      "Tilstand"@da
    ]
    identity id -> unknown

    affectsMovement -> Movement
  end

  entity ExpansiveMode is
    @rdfs:subClassOf = Mode
    @skos:prefLabel = [
      "Expansive Mode"@en
      "Ekspansiv tilstand"@da
    ]
    identity id -> unknown

    stimulatesAffinitiveMovement -> AffinitiveMovement
  end

  entity DefensiveMode is
    @rdfs:subClassOf = Mode
    @skos:prefLabel = [
      "Defensive Mode"@en
      "Defensiv tilstand"@da
    ]
    identity id -> unknown

    stimulatesDefinitiveMovement -> DefinitiveMovement
  end

  entity Movement is
    @rdfs:subClassOf = learn:Action
    @skos:prefLabel = [
      "Movement"@en
      "Bevægelse"@da
    ]
    identity id -> unknown

    affectsResultingLearning -> TentacularLearning
  end

  entity AffinitiveMovement is
    @rdfs:subClassOf = Movement
    @skos:prefLabel = [
      "Affinitive Movement"@en
      "Affinitiv bevægelse"@da
    ]
    identity id -> unknown

    DeepensLearning -> TentacularLearning
  end

  entity DefinitiveMovement is
    @rdfs:subClassOf = Movement
    @skos:prefLabel = [
      "Definitive Movement"@en
      "Definitiv bevægelse"@da
    ]
    identity id -> unknown
  end

  entity Prelearned

;  entity World
end