module learn_tentacular learn10tac <https://purl.org/learn/tentacular#> is

  import [ dc learn skos xsd ]

  @skos:prefLabel = [
    "Tentacular Learning Ontology"@en
    "Ontogogi om tentakulær læring"@da
  ]
  @dc:description = "Domain-specific ontology for Tentacular Learning as defined by Ernst Schraube"@en
  @dc:created = @xsd:date(2024-04-26)
  @dc:creator = <https://dr.jones.dk/me/#me>
  @dc:license = <https://spdx.org/licenses/AGPL-3.0-or-later>

  structure WorldingPracticeLearning is
    @rdfs:subClassOf = learn:Process
    @skos:prefLabel = [
      "Learning as a Worlding Practice"@en
      "Læring som en verdeningspraksis"@da
    ]
    @dc:description = [
      "The process of learning viewed as an affinitive dialogue with the surrounding world"@en
      "Læringsproces anskuet som en gensidig dialog (affinitet) med den omkringliggende verden"@da
    ]
    @rdfs:disjointWith = BisectedLearning
    isPracticedBy -> learn:Learner
    isModulatedBy -> Mode
    involvesMovement -> Movement
  end

  entity TentacularLearning is
    @rdfs:subClassOf = learn:Cognition
    @skos:prefLabel = [
      "Tentakular Learning"@en
      "Tentakulær læring"@da
    ]
    identity id -> unknown
  end

  entity ActionReason is
    @skos:prefLabel = [
      "Action Reason"@en
      "Aktionsgrund"@da
    ]
    @dc:description = [
      "The subjective reason by the learner for initiating a learning process"@en
      "En subjektiv grund hos eleven til at igangsætte en læringsproces"@da
    ]
    identity id -> unknown

    reasonedByLearner -> learn:Learner
    affectsMode -> Mode
  end

  entity ExpansiveReason is
    @rdfs:subClassOf = ActionReason
    @skos:prefLabel = [
      "Expansive Reason"@en
      "Ekspansiv grund"@da
    ]
    identity id -> unknown

    causesExpansiveMode -> ExpansiveMode
  end

  entity DefensiveReason is
    @rdfs:subClassOf = ActionReason
    @skos:prefLabel = [
      "Defensive Reason"@en
      "Defensiv grund"@da
    ]
    identity id -> unknown

    causesDefensiveMode -> DefensiveMode
  end

  entity ReasoningTrap is
    @skos:prefLabel = [
      "Reasoning trap"@en
      "Fejlslutning"@da
    ]
    @dc:description = [
      "typical pitfalls in the construction of subjective reasons for action towards learning"@en
      "typiske faldgruber i konstruktionen af subjektive grunde til at igangsætte en læringsproces"@da
    ]
    identity id -> unknown

    trapsaffectsReason -> ActionReason
  end

  entity OnlineModeTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Online Mode Habit Trap"@en
      "Online-aktivitetsvanefælde"@da
    ]
    @dc:description = [
      "Considering the online mode and the use of digital devices as absolutely helpful and expanding learning."@en
      "Anskuelsen af online-aktivitet og brug af digitalt udstyr som altid hjælpsomt og læringsudvidende."@da
    ]
    identity id -> unknown
  end

  entity BisectedLearningTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Trap of Bisected Learning"@en
      "Fælde ved tvedelt læring"@da
    ]
    @dc:description = [
      "Deprioritization of the content dimension of learning, caused by bisected learning excluding learners from influence on it."@en
      "Nedprioritering af den indholdsdimensionen af læring, fordi tvedelt læring udelukker elever indflydelse herpå."@da
    ]
    identity id -> unknown
  end

  entity UncertainnessEffortlessnessTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Trap of Uncertainness and Effortlessness"@en
      "Uvisheds- og ubesværethedsfælde"@da
    ]
    @skos:altLabel = [
      "Trap of Uncertainness"@en
      "Trap of Effortlessness"@en
      "Uvishedsfælde"@da
      "Ubesværethedsfælde"@da
    ]
    @dc:description = [
      "Equating swiftness in arriving at a conclusion with learning progress."@en
      "Forveksling af hurtigt at nå til en løsning med læringsfremskridt."@da
    ]
    identity id -> unknown
  end

  entity DialogueReductionTrap is
    @rdfs:subClassOf = ReasoningTrap
    @skos:prefLabel = [
      "Online dialogue-reduction habit trap"@en
      "Online-dialogreduktionsvanefælde"@da
    ]
    @dc:description = [
      "Reducing dialogue to the operative exchange and back and forth of perspectives."@en
      "Reduktion af samtale til operativ udveksling af perspektiver."@da
    ]
    identity id -> unknown
  end

  entity Mode is
    @skos:prefLabel = [
      "Mode"@en
      "Tilstand"@da
    ]
    identity id -> unknown

    affectsMovement -> Movement
  end

  entity ExpansiveMode is
    @rdfs:subClassOf = Mode
    @skos:prefLabel = [
      "Expansive Mode"@en
      "Ekspansiv tilstand"@da
    ]
    identity id -> unknown

    stimulatesAffinitiveMovement -> AffinitiveMovement
  end

  entity DefensiveMode is
    @rdfs:subClassOf = Mode
    @skos:prefLabel = [
      "Defensive Mode"@en
      "Defensiv tilstand"@da
    ]
    identity id -> unknown

    stimulatesDefinitiveMovement -> DefinitiveMovement
  end

  entity Movement is
    @rdfs:subClassOf = learn:Action
    @skos:prefLabel = [
      "Movement"@en
      "Bevægelse"@da
    ]
    identity id -> unknown

    affectsResultingLearning -> TentacularLearning
  end

  entity AffinitiveMovement is
    @rdfs:subClassOf = Movement
    @skos:prefLabel = [
      "Affinitive Movement"@en
      "Affinitiv bevægelse"@da
    ]
    identity id -> unknown

    DeepensLearning -> TentacularLearning
  end

  entity DefinitiveMovement is
    @rdfs:subClassOf = Movement
    @skos:prefLabel = [
      "Definitive Movement"@en
      "Definitiv bevægelse"@da
    ]
    identity id -> unknown
  end

  ;; the "evaluation"
  entity Evaluation

  entity Prelearned

;  entity World
end